C[omp]ute

From: andrew cooke <andrew@...>

Date: Sun, 15 Apr 2012 22:35:58 -0300

This is related to the SO question http://stackoverflow.com/questions/10161971
which is playing around with those puzzles where you need to make some number
form a series of digits and various mathematical operators.

The problem being that the problem assumes infix maths, which is a pain if
you're working with a prefix language like lisp.

So what this code does is take two lists - one of operators, and one of
digits, and generates an ast that evaluates correctly, given the precedence of
the operators.

(def default-priorities
  {'+ 1, '- 1, '* 2, '/ 2, '& 3})

(defn- extend-tree [tree priorities operator value]
  (if (seq? tree)
    (let [[op left right] tree
          [old new] (map priorities [op operator])]
      (if (> new old)
        (list op left (extend-tree right priorities operator value))
        (list operator tree value)))
    (list operator tree value)))

(defn priority-tree
  ([operators values] (priority-tree operators values default-priorities))
  ([operators values priorities] (priority-tree operators values priorities
  nil))
  ([operators values priorities tree]
    (if-let [operators (seq operators)]
      (if tree
        (recur
          (rest operators) (rest values) priorities
          (extend-tree tree priorities (first operators) (first values)))
        (let [[v1 v2 & values] values]
          (recur (rest operators) values priorities 
            (list (first operators) v1 v2))))
      tree)))

; [] [+ & *] [1 2 3 4] 1+23*4
; [+ 1 2] [& *] [3 4] - initial tree
; [+ 1 [& 2 3]] [*] [4] - binds more strongly than + so replace right-most
; node
; [+ 1 [* [& 2 3] 4]] [] [] - descend until do not bind more tightly, and
; extend

(println (priority-tree ['+ '& '*] [1 2 3 4])) ; 1+23*4
(println (priority-tree ['& '- '* '+ '&] [1 2 3 4 5 6])) ; 12 - 3*4 + 56

The output from the last two lines is:

(+ 1 (* (& 2 3) 4))
(+ (- (& 1 2) (* 3 4)) (& 5 6))

(I should have explained earlier that "&" is the pseudo-operator to combine
two digits into a number, so (& 1 2) is 12).

I know it's not ground-breaking or super-exciting, but it was fun to write...

Andrew